Hallo Zusammen.

Ich hoffe, dass mir hier jemand helfen kann.

Ich muß Loginscripte mit VB erstellen und diese per Gruppenrichtlinie zuweisen.
Alles auch eigentlich nicht das große Problem,........aber

Ich bekomme die Homeverzeichnisse nicht mit einer Variablen gemappt. Die Variable wäre & UserName & "$"!!!
Es erscheint immer die Fehlermeldung "Netzwerkpfad nicht gefunden"! Die Freigabe lautet aber genau so. Normalerweise müsste es mit der Option \\Servername\HOME\&UserName& "$" funktionieren.

Ich habe mir auch schon aus dem Netz ein Beispielscript gezogen, das alles genau eräutert und auch funktionsfähig sein soll. Aber bei dem bekomme ich auch die gleiche Fehlermeldung.
GEnauso habe ich auch schon die Freigabe geändert und das Loginscript angepasst. Gleich Fehlermeldung.

Hat irgend jemand eine gute Idee, oder evtl. ein Beispielscript??? Wäer eine Supesache, wenn Ihr mir helfen könntet.

Danke im Voraus

Gruß

Einsteiger 74

das logonscript

ich benutze zusaetzlich noch eine www siete zum anzeigen der resultate , spwie wenn ich jemandenen nerven mochte kommt der sprchasistent von xp zu wort.

gruss koni




'================================================= =========================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalSCRIPT(TM)
'
' NAME: logon.vbs
'
' AUTHOR: Ian Morrish,edit Koni Dambeck
' DATE : 5/7/2000 edit 7/12/2002
'
' COMMENT: This file must be copied to all domain controlers
'
'================================================= =========================
On Error Resume Next
Dim WshNetwork, asdPath, User
Dim strMappedDrives, strStatus
Dim IE

Const LOGONSERVER = "Sunny"
Const ADS_READONLY_SERVER = 4

' Display IE status window

Call CreateIE()
strStatus = "Logon Script v1.0 " & Date()
strStatus = strStatus & vbCRLF & "Logonserver " & LOGONSERVER
ie.document.all.wstatus.InnerText = strStatus

' Get the User ID

Set WSHNetwork = WScript.CreateObject("WScript.Network")
strUser = ""
While strUser = ""
strUser = WSHNetwork.UserName
Wend

ie.document.all.Msg1.InnerText = strUser
strStatus = strStatus & vbCRLF & "Hello " & strUser & "..."
ie.document.all.wstatus.InnerText = strStatus

call main()

strStatus = strStatus & vbCRLF & "Network Logon fertig..."
ie.document.all.wstatus.InnerText = strStatus


' Close IE status window

If not ie.document.all.holdit.checked then
ie.quit()
End if

' End of logon script

Public Sub Main()

'Main loop to detect group that user belongs to
adsPath = "WinNT://" & LOGONSERVER & "/" & strUser
Set dso = GetObject("WinNT:")
Set objUser = dso.OpenDSObject(adsPath,"","", ADS_READONLY_SERVER)
For Each Prop In objUser.groups

Select Case Prop.Name

Case "Marketing"
Call Marketing()

Case "Buchhaltung"
Call Buchhaltung()

Case "GL"
Call GL()

'etc
End Select
Next 'Prop

End Sub

Sub Buchhaltung()

strStatus = strStatus & vbCRLF & "Mitglied Gruppe Buchhaltung..."
strStatus = strStatus & vbCRLF & "Mapping von L: auf \\" & LOGONSERVER & "\Buchhaltung erstellt..."
ie.document.all.wstatus.InnerText = strStatus

MapDrive "L:", "\\" & LOGONSERVER & "\Buchhaltung"

End Sub

Sub GL()

strStatus = strStatus & vbCRLF & "Mitglied Gruppe GL..."
strStatus = strStatus & vbCRLF & "Mapping von M: auf \\" & LOGONSERVER & "\GL erstellt..."
ie.document.all.wstatus.InnerText = strStatus

MapDrive "M:", "\\" & LOGONSERVER & "\GL"


End Sub

Sub Marketing()

strStatus = strStatus & vbCRLF & "Mitglied Gruppe Marketing..."
strStatus = strStatus & vbCRLF & "Mapping von H: auf \\" & LOGONSERVER & "\" & strUser & "$ erstellt..."
strStatus = strStatus & vbCRLF & "Mapping von K: auf \\" & LOGONSERVER & "\Marketing erstellt..."
ie.document.all.wstatus.InnerText = strStatus

strHomeDir = "\\" & LOGONSERVER & "\" & strUser & "$"

MapDrive "H:", strHomeDir

MapDrive "K:", "\\" & LOGONSERVER & "\Marketing"

End Sub

Sub CreateIE()

On Error Resume Next
Set IE = CreateObject("InternetExplorer.Application")
With IE
.navigate "\\" & LOGONSERVER & "\netlogon\logon.htm"
.resizable=0
.height=420
.width=350
.menubar=0
.toolbar=0
.statusBar=0
.visible=1
End With
Do while ie.Busy
' wait for page to load
Wscript.Sleep 100
Loop

End Sub

Sub MapDrive(strDrive,strShare)

On Error Resume Next
WSHNetwork.MapNetworkDrive strDrive, strShare

If Err.Number Then

WSHNetwork.RemoveNetworkDrive strDrive
WSHNetwork.MapNetworkDrive strDrive, strShare

End If

strMappedDrives = strMappedDrives & strDrive & " "
ie.document.all.Msg2.InnerText = strMappedDrives

End Sub

Ich danke Dir für das Script.

Werde es am Montag testen.

Gruß

Einsteiger 74